[AHK] 피파온라인3용 엑박패드 유저를 위한 도우미 ver 2.0

Tip/AHKmacro 2014. 4. 13. 06:15

안녕하세요.

과거에 올렸던 엑박패드 도우미 수정 버전입니다.

이전 버전에서 변경된것은

피온3 해상도, 창모드 상관없이 클릭 가능
클릭 동작 비활성클릭으로 처리
JOY8번(Start버튼) 1초 이상 꾹 누르면 =키 누른 효과(채팅차단)

아래 소스코드입니다.

#NoEnv
#SingleInstance force
#Persistent
SetBatchLines,-1
ListLines, Off
Menu,Tray,NoStandard
Menu,Tray,Add,블로그 방문,goBlog
Menu,Tray,Add
Menu,Tray,Add,도움말,trayPop
Menu,Tray,Add,종료,MacroExit
CoordMode, Pixel, Screen
CoordMode, Mouse, Screen
CoordMode, ToolTip, Screen
SetTitleMatchMode, 2
global winID:="ahk_class FIFANG"
gosub, trayPop
return

realWinGet(ByRef Xpos,ByRef Ypos,ByRef Width,ByRef Height){ ; 창 위치,크기
	WinGetPos, Xpos, Ypos, Width, Height, %winID%
	WinGet,isMaxmize,MinMax,%winID%
	WinGet,WinStyle,Style,%winID%
	if ( isMaxmize = 0 and WinStyle <> 0x96000000){
		SysGet,xframe,7
		SysGet,yframe,8
		SysGet,titlebar,4
		Xpos:=Xpos+xframe
		Ypos:=Ypos+titlebar+yframe
		Width:=Width-xframe*2
		Height:=Height-titlebar-yframe*2
	}
	return
}

postClick(pX,pY,cnt){
	realWinGet(Xpos,Ypos,Width,Height)
	if ( pX < 1 or pY < 1 ){
		pX:=Floor(Width/2+(Height*pX))
		pY:=Floor(Height*pY)
	}else{
		pX:=pX-Xpos
		pY:=pY-Ypos
	}
	ahkID:=WinExist(winID)
	Loop, % cnt
	{
		PostMessage, 0x200,, ((pY*65536)+pX),, ahk_id %ahkID%         ;Mouse move
		Sleep,100
		PostMessage, 0x201, 0x0001, ((pY*65536)+pX),, ahk_id %ahkID%         ;WM_LBUTTONDOWN
		Sleep,20
		PostMessage, 0x202 , 0, ((pY*65536)+pX),, ahk_id %ahkID%               ;WM_LBUTTONUP
	}
	return
}

pysMsg(key){
	IfWinActive,% winID
	{	
		Send {%key% down}
		Sleep,50
		Send {%key% up}
	}else{
		WinGetTitle,otherWin,A
		WinActivate,%winID%
		Sleep,400
		Send {%key% down}
		Sleep,50
		Send {%key% up}
		WinActivate,%otherWin%
	}
}

escAndChat(){
	IfWinActive,%winID%
	{
		KeyWait, Joy8, T1.0
		if ErrorLevel
			pysMsg("=")
		else
			pysMsg("ESC")
	}
	return
}

Joy7::postClick(0.6,0.94,1)

Joy8::escAndChat()

goBlog:
Run, http://w3tech.tistory.com/214
return

trayPop:
TrayTip, XBoxPad 도우미 ver 2.0, 패드 BACK 버튼 = 피온3 ▶(Next) 클릭`n패드 START 버튼 = 키보드 ESC`n패드 START 버튼 1초 이상 누르면 키보드 = (채팅차단), 3
return

MacroExit:
ExitApp
return

컴파일한 실행파일입니다.

XBOXpadHelperMini.zip